private void autowireByDefinedSetters( any targetObj, any targetObjMetadata )

Autowires by defined setters.

Parameters:

any targetObj

any targetObjMetadata

Code:

	<cffunction name="autowireByDefinedSetters" access="private" returntype="void" output="false"
		hint="Autowires by defined setters.">
		<cfargument name="targetObj" type="any" required="true" />
		<cfargument name="targetObjMetadata" type="any" required="true" />

		<cfset var beanFactory = getProperty(getProperty("beanFactoryName")) />
		<cfset var functionMetadata = "" />
		<cfset var setterName = "" />
		<cfset var beanName = "" />
		<cfset var access = "" />
		<cfset var i = 0 />

		
		<cfif StructKeyExists(arguments.targetObjMetadata, "functions")>
			<cfloop from="1" to="#ArrayLen(arguments.targetObjMetadata.functions)#" index="i">
				<cfset functionMetadata = arguments.targetObjMetadata.functions[i] />
			
				
				<cfif StructKeyExists(functionMetadata, "access")>
					<cfset access = functionMetadata.access />
				<cfelse>
					<cfset access = "public" />
				</cfif>
				
				
				<cfif Left(functionMetadata.name, 3) EQ "set" AND Arraylen(functionMetadata.parameters) EQ 1 AND access NEQ "private">
					
						  
					<cfset setterName = Mid(functionMetadata.name, 4, Len(functionMetadata.name) - 3) />
					
					
					<cfif beanFactory.containsBean(setterName)>
						<cfset beanName = setterName />
					<cfelseif ArrayLen(functionMetadata.parameters) GT 0
						AND StructKeyExists(functionMetadata.parameters[1], "type")>
						<cfset beanName = beanFactory.findBeanNameByType(functionMetadata.parameters[1].type) />
					<cfelse>
						<cfset beanName = "" />
					</cfif>
										
					
					<cfif Len(beanName)>
						<cfinvoke component="#arguments.targetObj#" method="set#setterName#">
							<cfinvokeargument name="#functionMetadata.parameters[1].name#" value="#beanFactory.getBean(beanName)#" />
						</cfinvoke>	
					</cfif>			  
				</cfif>
			</cfloop>
		</cfif>
	</cffunction> 

private void autowireByDynamicMethodGeneration( string targetKey, any targetObj, any targetObjMetadata, string autowireAttributeName )

Autowires by dynamic method generation.

Parameters:

string targetKey

any targetObj

any targetObjMetadata

string autowireAttributeName

Code:

	<cffunction name="autowireByDynamicMethodGeneration" access="private" returntype="void" output="false"
		hint="Autowires by dynamic method generation.">
		<cfargument name="targetKey" type="string" required="true" />
		<cfargument name="targetObj" type="any" required="true" />
		<cfargument name="targetObjMetadata" type="any" required="true" />
		<cfargument name="autowireAttributeName" type="string" required="true" />

		<cfset var beanFactory = getProperty(getProperty("beanFactoryName")) />
		<cfset var autowireBeanNames = "" />
		<cfset var beanName = "" />
		<cfset var autowireCfc = "" />
		<cfset var targetType = "" />
		<cfset var targetName = "" />
		<cfset var i = 0 />

		
		<cfif StructKeyExists(arguments.targetObjMetadata, arguments.autowireAttributeName)>
			
			
			<cfset autowireBeanNames = ListToArray(arguments.targetObjMetadata[arguments.autowireAttributeName]) />
			
			
			<cfset autowireCfc = createAutowireDynamicMethodsComponent(autowireBeanNames) />
			
			
			<cfloop from="1" to="#ArrayLen(autowireBeanNames)#" index="i">
				
				<cfset beanName = Trim(autowireBeanNames[i]) />
				
				
				<cfset arguments.targetObj["_methodInject"] = autowireCfc["_methodInject"] />

				
				<cfif NOT StructKeyExists(arguments.targetObj, "get" & beanName)>
					<cfset arguments.targetObj._methodInject("get" & beanName, autowireCfc["get" & beanName]) />
				</cfif>
				
				
				<cfif NOT StructKeyExists(arguments.targetObj, "set" & beanName)>
					<cfset arguments.targetObj._methodInject("set" & beanName, autowireCfc["set" & beanName]) />
				</cfif>
					
				
				<cfif beanFactory.containsBean(beanName)>
					<cfinvoke component="#arguments.targetObj#" method="set#beanName#">
						<cfinvokeargument name="#beanName#" value="#beanFactory.getBean(beanName)#" />
					</cfinvoke>
				<cfelse>
					<cfset targetType = ListFirst(arguments.targetKey, "_") />
					<cfset targetName = ListDeleteAt(arguments.targetKey, 1, "_") />
					<cfthrow type="MachII.properties.ColdspringProperty"
						message="Cannot find bean named '#beanName#' to autowire by method injection in a #targetType# named '#targetName#' in module '#getAppManager().getModuleName()#'."
						detail="Check that there is a bean named '#beanName#' defined in your ColdSpring bean factory." />
				</cfif>
				
				
				<cfset StructDelete(arguments.targetObj, "_methodInject") />
			</cfloop>
		</cfif>	
	</cffunction> 

private array buildConfigFilePaths( string baseConfigFilePath )

Builds an array of config file paths.

Parameters:

string baseConfigFilePath

Code:

	<cffunction name="buildConfigFilePaths" access="private" returntype="array" output="false"
		hint="Builds an array of config file paths.">
		<cfargument name="baseConfigFilePath" type="string" required="true" />
		
		<cfset var configFiles = ArrayNew(1) />
		<cfset var imports = StructNew() />
		<cfset var i = "" />
		
		
		<cfset getProperty(getProperty("beanFactoryName")).findImports(imports, arguments.baseConfigFilePath) />
		
		<cfloop collection="#imports#" item="i">
			<cfset ArrayAppend(configFiles, i) />
		</cfloop>
		
		<cfreturn configFiles />
	</cffunction> 

public void configure( )

I initialize this property during framework startup.

Parameters:

Code:

	<cffunction name="configure" access="public" returntype="void" output="false"
		hint="I initialize this property during framework startup.">
		
		
		<cfset var bf = "" />
		<cfset var factoryKey = "" />
		<cfset var i = 0 />
		
		
		<cfset var propertyManager = getPropertyManager() />
	
		
		<cfset var serviceDefXmlLocation = "" />
		
		
		<cfset var defaultProperties = StructNew() />
		
		
		<cfset var defaultAttributes = StructNew() />
		
		
		<cfset var bfUtils = CreateObject("component", "coldspring.beans.util.BeanFactoryUtils").init() />

		<cfset var parentBeanFactoryScope = getParameter("parentBeanFactoryScope", "application") />
		<cfset var parentBeanFactoryKey = getParameter("parentBeanFactoryKey", "") />

		<cfset var localBeanFactoryKey = getParameter("beanFactoryPropertyName", bfUtils.DEFAULT_FACTORY_KEY) />
		
		
		<cfset var autowireAttributeName = getParameter("autowireAttributeName", "depends") />
		
		
		<cfif isParameterDefined("cfcGenerationLocation")>
			<cfset setCfcGenerationLocation(ExpandPath(getParameter("cfcGenerationLocation"))) />
		<cfelse>
			<cfset setCfcGenerationLocation(GetDirectoryFromPath(GetCurrentTemplatePath())) />
		</cfif>
		
		
		<cfif isParameterDefined("dotPathTocfcGenerationLocation")>
			<cfset setDotPathToCfcGenerationLocation(getParameter("dotPathTocfcGenerationLocation") & ".") />
		<cfelse>
			<cfset setDotPathToCfcGenerationLocation("") />
		</cfif>
		
		
		<cfif isParameterDefined("configFile")>
			<cfset serviceDefXmlLocation = getParameter("configFile") />
		<cfelse>
			<cfthrow type="ColdspringProperty.configFileParameterNotDefined"
				message="You must specify a parameter named 'configFile'." />
		</cfif>
		
		
		<cfset StructAppend(defaultProperties, propertyManager.getProperties()) />
		
		
		<cfif IsObject(getAppManager().getParent())>
			<cfset StructAppend(defaultProperties, propertyManager.getParent().getProperties(), false) />
		</cfif>		
		
		
		<cfloop collection="#defaultProperties#" item="i">
			<cfif IsSimpleValue(defaultProperties[i]) AND REFindNoCase("\${(.)*?}", defaultProperties[i])>
				<cfset defaultProperties[i] = Evaluate(Mid(defaultProperties[i], 3, Len(defaultProperties[i]) -3)) />
			</cfif>
		</cfloop>
		
		
		<cfset bf = CreateObject("component", "coldspring.beans.DefaultXmlBeanFactory").init(defaultAttributes, defaultProperties) />
		
		
		<cfif len(parentBeanFactoryKey) AND bfUtils.namedFactoryExists(parentBeanFactoryScope, parentBeanFactoryKey)>
			<cfset bf.setParent(bfUtils.getNamedFactory(parentBeanFactoryScope, parentBeanFactoryKey))/>
		</cfif>
		
		
		<cfif getParameter("configFilePathIsRelative", false)>
			<cfset serviceDefXmlLocation = ExpandPath(serviceDefXmlLocation) />
		</cfif>
		
		
		<cfset request._MachIIAppManager = getAppManager() />
		
		
		<cfset bf.loadBeansFromXmlFile(serviceDefXmlLocation, true) />

		
		<cfset setProperty("beanFactoryName", localBeanFactoryKey) />
		<cfset setProperty(localBeanFactoryKey, bf) />
		
		
		<cfset factoryKey = localBeanFactoryKey />
		
		
		<cfif Len(getAppManager().getModuleName()) AND getAppManager().getParent().getPropertyManager().isPropertyDefined(localBeanFactoryKey)>
			<cfset factoryKey = factoryKey & "_" & getAppManager().getModuleName() />
		</cfif>
		
		
		<cfif getParameter("placeFactoryInApplicationScope", false)>
			<cfset bfUtils.setNamedFactory("application", factoryKey, bf) />
		</cfif>
		<cfif getParameter("placeFactoryInServerScope", false)>
			<cfset bfUtils.setNamedFactory("server", factoryKey, bf) />
		</cfif>
		
		
		<cfif getParameter("resolveMachIIDependencies", false)>
			<cfset resolveDependencies(autowireAttributeName) />
		</cfif>
		
		
		<cfif getParameter("generateRemoteProxies", false)>
			<cfset generateRemoteProxies() />
		</cfif>
		
		
		<cfif isParameterDefined("beansToMachIIProperties")>
			<cfif IsStruct(getParameter("beansToMachIIProperties"))>
				<cfset referenceBeansToMachIIProperties(getParameter("beansToMachIIProperties")) />
			<cfelse>
				<cfthrow type="ColdspringProperty.beansToMachIIPropertiesInvalidType"
					message="The value of a parameter named 'beansToMachIIProperties' must contain a struct." />
			</cfif>
		</cfif>
				
		
		<cfset setConfigFilePaths(buildConfigFilePaths(serviceDefXmlLocation)) />
		<cfset setLastReloadHash(getConfigFileReloadHash()) />
		<cfset setLastReloadDatetime(Now()) />
	</cffunction> 

public void generateRemoteProxies( )

Generates all the remote proxies that are of type 'coldspring.aop.framework.RemoteFactoryBean'.

Parameters:

Code:

	<cffunction name="generateRemoteProxies" access="public" returntype="void" output="false"
		hint="Generates all the remote proxies that are of type 'coldspring.aop.framework.RemoteFactoryBean'.">
		
		<cfset var beanFactory = getProperty(getProperty("beanFactoryName")) />
		
		<cfset var remoteProxyNames = beanFactory.findAllBeanNamesByType("coldspring.aop.framework.RemoteFactoryBean", false) />
		<cfset var remoteProxy = "" />
		<cfset var i = "" />
		
		
		<cfloop from="1" to="#ArrayLen(remoteProxyNames)#" index="i">
			
			<cfset remoteProxy = beanFactory.getBean("&" & remoteProxyNames[i]) />
			
			
			<cfif remoteProxy.isConstructed()>
				<cfset remoteProxy.destoryRemoteProxy() />
			</cfif>
			
			
			<cfset remoteProxy.createRemoteProxy() />
		</cfloop>
	</cffunction> 

private string getConfigFileReloadHash( )

Get the current reload hash of the bean factory config file and imports files. The hash is based on dateLastModified and size of the file.

Parameters:

Code:

	<cffunction name="getConfigFileReloadHash" access="private" returntype="string" output="false"
		hint="Get the current reload hash of the bean factory config file and imports files.  The hash is based on dateLastModified and size of the file.">

		<cfset var configFilePaths = getConfigFilePaths() />
		<cfset var directoryResults = "" />
		<cfset var hashableString = "" />
		<cfset var i = "" />

		<cfloop from="1" to="#ArrayLen(configFilePaths)#" index="i">
			<cfdirectory action="LIST" directory="#GetDirectoryFromPath(configFilePaths[i])#" 
				name="directoryResults" filter="#GetFileFromPath(configFilePaths[i])#" />
			<cfset hashableString = hashableString & directoryResults.dateLastModified & directoryResults.size />
		</cfloop>

		<cfreturn Hash(hashableString) />
	</cffunction> 

private void getConfigurableProperties( struct targets )

Get the configurable property targets.

Parameters:

struct targets

Code:

	<cffunction name="getConfigurableProperties" access="private" returntype="void" output="false"
		hint="Get the configurable property targets.">
		<cfargument name="targets" type="struct" required="true" />
		
		<cfset var propertyManager = getAppManager().getPropertyManager() />
		<cfset var configurablePropertyNames = propertyManager.getConfigurablePropertyNames() />
		<cfset var i = 0 />
		
		
		<cfloop from="1" to="#ArrayLen(configurablePropertyNames)#" index="i">
			<cfset targets["property_" & configurablePropertyNames[i]] = propertyManager.getProperty(configurablePropertyNames[i]) />
		</cfloop>
	</cffunction> 

private void getFilters( struct targets )

Get the filter targets.

Parameters:

struct targets

Code:

	<cffunction name="getFilters" access="private" returntype="void" output="false"
		hint="Get the filter targets.">
		<cfargument name="targets" type="struct" required="true" />
		
		<cfset var filterManager = getAppManager().getFilterManager() />
		<cfset var filterNames = filterManager.getFilterNames() />
		<cfset var i = 0 />
		
		
		<cfloop from="1" to="#ArrayLen(filterNames)#" index="i">
			<cfset targets["filter_" & filterNames[i]] = filterManager.getFilter(filterNames[i]) />
		</cfloop>
	</cffunction> 

private void getListeners( struct targets )

Gets the listener targets.

Parameters:

struct targets

Code:

	<cffunction name="getListeners" access="private" returntype="void" output="false"
		hint="Gets the listener targets.">
		<cfargument name="targets" type="struct" required="true" />
		
		<cfset var listenerManager = getAppManager().getListenerManager() />
		<cfset var listenerNames = listenerManager.getListenerNames() />
		<cfset var i = 0 />
		
		
		<cfloop from="1" to="#ArrayLen(listenerNames)#" index="i">
			<cfset targets["listener_" & listenerNames[i]] = listenerManager.getListener(listenerNames[i]) />
		</cfloop>
	</cffunction> 

private void getPlugins( struct targets )

Get the plugin targets.

Parameters:

struct targets

Code:

	<cffunction name="getPlugins" access="private" returntype="void" output="false"
		hint="Get the plugin targets.">
		<cfargument name="targets" type="struct" required="true" />
		
		<cfset var pluginManager = getAppManager().getPluginManager() />
		<cfset var pluginNames = pluginManager.getPluginNames() />
		<cfset var i = 0 />
		
		
		<cfloop from="1" to="#ArrayLen(pluginNames)#" index="i">
			<cfset targets["plugin_" & pluginNames[i]] = pluginManager.getPlugin(pluginNames[i]) />
		</cfloop>
	</cffunction> 

private void resolveDependencies( string autowireAttributeName )

Resolves Mach-II dependencies.

Parameters:

string autowireAttributeName

Code:

	<cffunction name="resolveDependencies" access="private" returntype="void" output="false"
		hint="Resolves Mach-II dependencies.">
		<cfargument name="autowireAttributeName" type="string" required="true" />
		
		<cfset var targets = StructNew() />
		<cfset var targetObj = 0 />
		<cfset var targetMetadata = "" />
		<cfset var key = "" />
		
		
		<cfset getListeners(targets) />
		<cfset getFilters(targets) />
		<cfset getPlugins(targets) />
		<cfset getConfigurableProperties(targets) />
		
		<cfloop collection="#targets#" item="key">
			
			<cfset targetObj = targets[key] />
			
			
			<cfset targetMetadata = GetMetadata(targetObj) />
			
			
			<cfset autowireByDynamicMethodGeneration(key, targetObj, targetMetadata, arguments.autowireAttributeName) />

			
			<cfset autowireByDefinedSetters(targetObj, targetMetadata) />
		</cfloop>
		
	</cffunction> 

public boolean shouldReloadConfig( )

Checks if the bean factory config file or any of its' imports have changed.

Parameters:

Code:

	<cffunction name="shouldReloadConfig" access="public" returntype="boolean" output="false"
		hint="Checks if the bean factory config file or any of its' imports have changed.">
		
		<cfset var result = false />
		
		<cfif CompareNoCase(getLastReloadHash(), getConfigFileReloadHash()) NEQ 0>
			<cfset result = true />
		</cfif>
		
		<cfreturn result />
	</cffunction>