private void addLogger( string loggerName, AbstractLogger logger )

Adds a logger to the struct of registered loggers.

Parameters:

string loggerName

AbstractLogger logger

Code:

	<cffunction name="addLogger" access="private" returntype="void" output="false"
		hint="Adds a logger to the struct of registered loggers.">
		<cfargument name="loggerName" type="string" required="true" />
		<cfargument name="logger" type="MachII.logging.loggers.AbstractLogger" required="true" />
		
		<cfif StructKeyExists(variables.loggers, arguments.loggerName)>
			<cfthrow type="MachII.properties.LoggingProperty"
				message="A logger named '#arguments.loggerName#' already exists in module '#getAppManager().getModuleName()#'. Logger names must be unique." />
		<cfelse>
			<cfset variables.loggers[arguments.loggerName] = arguments.logger />
		</cfif>
	</cffunction> 

public void configure( )

Configures the property.

Parameters:

Code:

	<cffunction name="configure" access="public" returntype="void" output="false"
		hint="Configures the property.">
		
		<cfset var params = getParameters() />
		<cfset var defaultLoggerParameters = StructNew() />
		<cfset var loggers = StructNew() />
		<cfset var logFactoryLogAdapters = StructNew() />
		<cfset var currentLogAdapters = ArrayNew(1) />
		<cfset var moduleName = getModuleName() />
		<cfset var utils = getAppManager().getUtils() />
		<cfset var temp = "" />
		<cfset var key = "" />
		<cfset var i = 0 />
		
		
		<cfloop collection="#params#" item="key">
			<cfif IsStruct(params[key])>
				<cfset configureLogger(key, getParameter(key)) />
			</cfif>
		</cfloop>
		
		
		<cfif NOT StructCount(getLoggers())>
			<cfset defaultLoggerParameters.type = variables.defaultLoggerType />
			<cfset configureLogger(variables.defaultLoggerName, defaultLoggerParameters) />
		</cfif>
		
		
		<cfset loggers = getLoggers() />
		
		
		<cfloop collection="#loggers#" item="key">
			<cfset loggers[key].configure() />
			<cfset getAppManager().getLogFactory().addLogAdapter(moduleName & "-" & loggers[key].getLoggerId(), loggers[key].getLogAdapter()) />
			<cfset ArrayAppend(currentLogAdapters, loggers[key].getLogAdapter()) />
		</cfloop>
		
		
		<cfif IsObject(getAppManager().getParent())>
			<cfset logFactoryLogAdapters = getAppManager().getLogFactory().getLogAdapters() />
			<cfloop from="1" to="#ArrayLen(currentLogAdapters)#" index="i">
				<cfloop collection="#logFactoryLogAdapters#" item="key">
					<cfif ListFirst(key, "-") EQ moduleName 
						AND NOT utils.assertSame(logFactoryLogAdapters[key], currentLogAdapters[i])>
						<cfset StructDelete(logFactoryLogAdapters, key, false) />
						<cfbreak />
					</cfif>
				</cfloop>
			</cfloop>
		</cfif>
		
		
		<cfif NOT getParameter("loggingEnabled", true)>
			<cfset getAppManager().getLogFactory().disableLogging() />
		</cfif>
	</cffunction> 

private void configureLogger( string loggerName, struct parameters )

Configures an logger.

Parameters:

string loggerName

struct parameters

Code:

	<cffunction name="configureLogger" access="private" returntype="void" output="false"
		hint="Configures an logger.">
		<cfargument name="loggerName" type="string" required="true"
			hint="Name of the logger." />
		<cfargument name="parameters" type="struct" required="true"
			hint="Parameters for this logger.">
		
		<cfset var type = "" />
		<cfset var logger = "" />
		<cfset var loggerId = createLoggerId(arguments.loggerName) />
		<cfset var moduleName = getModuleName() />
		<cfset var key = "" />		
		
		
		<cfif NOT StructKeyExists(arguments.parameters, "type")>
			<cfthrow type="MachII.properties.LoggingProperty"
				message="You must specify a 'type' for log adapter named '#arguments.loggerName#'." />
		</cfif>
		
		
		<cfloop collection="#arguments.parameters#" item="key">
			<cfset arguments.parameters[key] = bindValue(key, arguments.parameters[key]) />
		</cfloop>
		
		
		<cftry>
			<cfset logger = CreateObject("component", arguments.parameters.type).init(loggerId, arguments.parameters) />

			<cfcatch type="any">
				<cfif StructKeyExists(cfcatch, "missingFileName")>
					<cfthrow type="MachII.logging.CannotFindLogger"
						message="The LoggingProperty in module named '#getAppManager().getModuleName()#' cannot find a logger located at '#arguments.parameters.type#'."
						detail="Please check that this logger exists and that there is not a misconfiguration in the XML configuration file." />
				<cfelse>
					<cfrethrow />
				</cfif>
			</cfcatch>
		</cftry>
		
		
		<cfif logger.isOnRequestEndAvailable()>
			<cfset getAppManager().getRequestManager().addOnRequestEndCallback(logger, "onRequestEnd", moduleName) />
		</cfif>
		
		
		<cfif logger.isPrePostRedirectAvailable()>
			<cfset getAppManager().getRequestManager().addPreRedirectCallback(logger, "preRedirect", moduleName) />
			<cfset getAppManager().getRequestManager().addPostRedirectCallback(logger, "postRedirect", moduleName) />
		</cfif>
		
		
		<cfset addLogger(arguments.loggerName, logger) />
	</cffunction> 

private string createLoggerId( string loggerName )

Creates a logger id.

Parameters:

string loggerName

Code:

	<cffunction name="createLoggerId" access="private" returntype="string" output="false"
		hint="Creates a logger id.">
		<cfargument name="loggerName" type="string" required="true" />
		<cfreturn Hash(arguments.loggerName & getModuleName() & GetTickCount() & RandRange(0, 10000)& RandRange(0, 10000)) />
	</cffunction> 

public void disableLogging( )

Disables logging.

Parameters:

Code:

	<cffunction name="disableLogging" access="public" returntype="void" output="false"
		hint="Disables logging.">
		<cfset getAppManager().getLogFactory().disableLogging() />
	</cffunction> 

public void enableLogging( )

Enables logging.

Parameters:

Code:

	<cffunction name="enableLogging" access="public" returntype="void" output="false"
		hint="Enables logging.">
		<cfset getAppManager().getLogFactory().enableLogging() />
	</cffunction> 

public AbstractLogger getLoggerByName( string loggerName )

Gets a logger by name.

Parameters:

string loggerName

Code:

	<cffunction name="getLoggerByName" access="public" returntype="MachII.logging.loggers.AbstractLogger" output="false"
		hint="Gets a logger by name.">
		<cfargument name="loggerName" type="string" required="true" />
		<cfreturn variables.loggers[arguments.loggerName] />
	</cffunction> 

public struct getLoggers( )

Gets all the registered loggers.

Parameters:

Code:

	<cffunction name="getLoggers" access="public" returntype="struct" output="false"
		hint="Gets all the registered loggers.">
		<cfreturn variables.loggers />
	</cffunction> 

private string getModuleName( )

Gets the module name.

Parameters:

Code:

	<cffunction name="getModuleName" access="private" returntype="string" output="false"
		hint="Gets the module name.">

		<cfset var moduleName = getAppManager().getModuleName() />
		
		<cfif NOT Len(moduleName)>
			<cfset moduleName = "_base_" />
		</cfif>

		<cfreturn moduleName />
	</cffunction> 

public boolean isLoggerDefined( string loggerName )

Checks if a logger is defined by name.

Parameters:

string loggerName

Code:

	<cffunction name="isLoggerDefined" access="public" returntype="boolean" output="false"
		hint="Checks if a logger is defined by name.">
		<cfargument name="loggerName" type="string" required="true" />
		<cfreturn StructKeyExists(variables.loggers, arguments.loggerName) />
	</cffunction>