private string createPersistId( )

Creates a persistId for use.

Parameters:

Code:

	<cffunction name="createPersistId" access="private" returntype="string" output="false"
		hint="Creates a persistId for use.">
		<cfreturn REReplace(CreateUUID(), "[[:punct:]]", "", "ALL") />
	</cffunction> 

private string createTimestamp( [date time="#Now()#"] )

Creates a timestamp which is safe to use as a key.

Parameters:

[date time="#Now()#"]

Code:

	<cffunction name="createTimestamp" access="private" returntype="string" output="false"
		hint="Creates a timestamp which is safe to use as a key.">
		<cfargument name="time" type="date" required="false" default="#Now()#" />
		<cfreturn REReplace(arguments.time, "[ts[:punct:][:space:]]", "", "ALL") />
	</cffunction> 

public AppManager getAppManager( )

Parameters:

Code:

	<cffunction name="getAppManager" access="public" returntype="MachII.framework.AppManager" output="false">
		<cfreturn variables.appManager />
	</cffunction> 

private Log getLog( )

Gets the log.

Parameters:

Code:

	<cffunction name="getLog" access="private" returntype="MachII.logging.Log" output="false"
		hint="Gets the log.">
		<cfreturn variables.log />
	</cffunction> 

public PropertyManager getPropertyManager( )

Parameters:

Code:

	<cffunction name="getPropertyManager" access="public" returntype="MachII.framework.PropertyManager" output="false">
		<cfreturn getAppManager().getPropertyManager() />
	</cffunction> 

public string getRedirectPersistParameter( )

Parameters:

Code:

	<cffunction name="getRedirectPersistParameter" access="public" returntype="string" output="false">
		<cfreturn variables.redirectPersistParameter />
	</cffunction> 

public string getRedirectPersistScope( )

Parameters:

Code:

	<cffunction name="getRedirectPersistScope" access="public" returntype="string" output="false">
		<cfreturn variables.redirectPersistScope />
	</cffunction> 

private struct getStorage( )

Helper function to get the event data store for persists.

Parameters:

Code:

	<cffunction name="getStorage" access="private" returntype="struct" output="false"
		hint="Helper function to get the event data store for persists.">
		
		<cfset var storage = StructGet(getRedirectPersistScope() & "." & getAppManager().getAppKey() & "._MachIIRequestRedirectPersistStorage") />
		
		
		<cfif NOT StructCount(storage)>

			<cflock name="_MachIIRequestRedirectPersistCreate" type="exclusive" timeout="5" throwontimeout="false">
				<cfif NOT StructCount(storage)>
					<cfset storage.data = StructNew() />
					<cfset storage.timestamps = StructNew() />
					<cfset storage.lastCleanup = createTimestamp() />
				</cfif>
			</cflock>

		</cfif>
		
		<cfreturn storage />
	</cffunction> 

public ThreadingAdapter getThreadingAdapter( )

Parameters:

Code:

	<cffunction name="getThreadingAdapter" access="public" returntype="MachII.util.threading.ThreadingAdapter" output="false">
		<cfreturn variables.threadingAdapter />
	</cffunction> 

public RequestRedirectPersist init( AppManager appManager )

Initializes the redirect persist machinery.

Parameters:

AppManager appManager

Code:

	<cffunction name="init" access="public" returntype="RequestRedirectPersist" output="false"
		hint="Initializes the redirect persist machinery.">
		<cfargument name="appManager" type="MachII.framework.AppManager" required="true" />

		<cfset setAppManager(arguments.appManager) />
		<cfset setLog(getAppManager().getLogFactory()) />

		<cfset setRedirectPersistParameter(getPropertyManager().getProperty("redirectPersistParameter")) />
		
		<cfif NOT ListFindNoCase("server,application,session", getPropertyManager().getProperty("redirectPersistScope"))>
			<cfthrow type="MachII.framework.InvalidRequestRedirectPersistScope"
				message="Invalid value for 'redirectPersistScope' property."
				detail="Valid values 'server', 'application' or 'session'." />
		<cfelse>
			<cfset setRedirectPersistScope(getPropertyManager().getProperty("redirectPersistScope")) />
		</cfif>

		<cfset setThreadingAdapter(getAppManager().getUtils().createThreadingAdapter()) />

		<cfreturn this />
	</cffunction> 

public struct read( struct eventArgs )

Gets a persisted event by id if found in event args.

Parameters:

struct eventArgs

Code:

	<cffunction name="read" access="public" returntype="struct" output="false"
		hint="Gets a persisted event by id if found in event args.">
		<cfargument name="eventArgs" type="struct" required="true"
			hint="The eventArgs struct is built before MachII.framework.Event is available." />
		
		<cfset var persistId = "" />
		<cfset var persistedData = StructNew() />
		<cfset var dataStorage = "" />
		<cfset var key = "" />
		<cfset var log = getLog() />
		
		
		<cfif StructKeyExists(arguments.eventArgs, getRedirectPersistParameter())>
			<cfset persistId = arguments.eventArgs[getRedirectPersistParameter()] />
			<cfset dataStorage = getStorage() />
			
			
			<cfif StructKeyExists(dataStorage.data, persistId)>
				<cfif log.isDebugEnabled()>
					<cfset log.debug("Found redirect persist event data under persist id '#persistId#'.") />
				</cfif>
				
				<cftry>
					
					<cfset persistedData = dataStorage.data[persistId]>
					<cfset StructDelete(dataStorage.data, persistId, false) />
					<cfset key = StructFindValue(dataStorage.timestamps, persistId, "one") />
					<cfset StructDelete(dataStorage.timestamps, key[1].key, false) />
					<cfcatch type="any">
						
					</cfcatch>
				</cftry>
			</cfif>
		</cfif>
		
		<cfreturn persistedData />
	</cffunction> 

public void reap( )

Reaps the storage of old redirect persists.

Parameters:

Code:

	<cffunction name="reap" access="public" returntype="void" output="false"
		hint="Reaps the storage of old redirect persists.">
		
		<cfset var diffTimestamp = createTimestamp(DateAdd("n", variables.cleanupDifference, now())) />
		<cfset var dataStorage = getStorage() />
		<cfset var dataTimestampArray = "" />
		<cfset var key = "" />
		<cfset var i = "" />
		<cfset var log = getLog() />
		
		<cflock name="_MachIIRequestRedirectPersistCleanup" type="exclusive" timeout="5" throwontimeout="false">
			
			<cfif log.isTraceEnabled()>
				<cfset log.trace("Reaping old redirect persists.") />
			</cfif>
			
			
			<cfset dataStorage.lastCleanup = createTimestamp() />
				
			
			<cfset dataTimestampArray = StructKeyArray(dataStorage.timestamps) />
			<cfset ArraySort(dataTimestampArray, "textnocase", "asc") />
			
			
			<cfloop from="1" to="#ArrayLen(dataTimestampArray)#" index="i">
				<cftry>
					<cfif (diffTimestamp - ListFirst(dataTimestampArray[i], "_")) GTE 0>
						
						<cfset key = dataTimestampArray[i] />
						<cfset StructDelete(dataStorage.timestamps, key, false) />
						<cfset StructDelete(dataStorage.data, ListLast(key, "_"), false) />
					<cfelse>
						<cfbreak />
					</cfif>
					<cfcatch type="any">
						
					</cfcatch>
				</cftry>
			</cfloop>
		
		</cflock>
	</cffunction> 

public string save( struct data )

Saves persisted event data and returns the persistId.

Parameters:

struct data

Code:

	<cffunction name="save" access="public" returntype="string" output="false"
		hint="Saves persisted event data and returns the persistId.">
		<cfargument name="data" type="struct" required="true" />
		
		<cfset var persistId = createPersistId() />
		<cfset var dataStorage = getStorage() />
		<cfset var log = getLog() />
		
		
		<cfset shouldCleanup() />
		
		<cfif log.isDebugEnabled()>
			<cfset log.debug("Saving redirect persist event data under persist id '#persistId#'.") />
		</cfif>
		
		
		<cfset dataStorage.data[persistId] = arguments.data />
		<cfset dataStorage.timestamps[createTimestamp() & "_" & persistId] = persistId />
		
		<cfreturn persistId />
	</cffunction> 

private void setAppManager( AppManager appManager )

Parameters:

AppManager appManager

Code:

	<cffunction name="setAppManager" access="private" returntype="void" output="false">
		<cfargument name="appManager" type="MachII.framework.AppManager" required="true" />
		<cfset variables.appManager = arguments.appManager />
	</cffunction> 

private void setLog( LogFactory logFactory )

Uses the log factory to create a log.

Parameters:

LogFactory logFactory

Code:

	<cffunction name="setLog" access="private" returntype="void" output="false"
		hint="Uses the log factory to create a log.">
		<cfargument name="logFactory" type="MachII.logging.LogFactory" required="true" />
		<cfset variables.log = arguments.logFactory.getLog(getMetadata(this).name) />
	</cffunction> 

private void setRedirectPersistParameter( string redirectPersistParameter )

Parameters:

string redirectPersistParameter

Code:

	<cffunction name="setRedirectPersistParameter" access="private" returntype="void" output="false">
		<cfargument name="redirectPersistParameter" type="string" required="true" />
		<cfset variables.redirectPersistParameter = arguments.redirectPersistParameter />
	</cffunction> 

private void setRedirectPersistScope( string redirectPersistScope )

Parameters:

string redirectPersistScope

Code:

	<cffunction name="setRedirectPersistScope" access="private" returntype="void" output="false">
		<cfargument name="redirectPersistScope" type="string" required="true" />
		<cfset variables.redirectPersistScope = arguments.redirectPersistScope />
	</cffunction> 

private void setThreadingAdapter( ThreadingAdapter threadingAdapter )

Parameters:

ThreadingAdapter threadingAdapter

Code:

	<cffunction name="setThreadingAdapter" access="private" returntype="void" output="false">
		<cfargument name="threadingAdapter" type="MachII.util.threading.ThreadingAdapter" required="true" />
		<cfset variables.threadingAdapter = arguments.threadingAdapter />
	</cffunction> 

private void shouldCleanup( )

Cleanups the data storage.

Parameters:

Code:

	<cffunction name="shouldCleanup" access="private" returntype="void" output="false"
		hint="Cleanups the data storage.">
		
		<cfset var diffTimestamp = createTimestamp(DateAdd("n", variables.cleanupDifference, now())) />
		<cfset var dataStorage = getStorage() />
		<cfset var threadingAdapter = "" />
		
		<cfif (diffTimestamp - dataStorage.lastCleanup) GTE 0>
		
			<cfset threadingAdapter = getThreadingAdapter() />
			
			<cflock name="_MachIIRequestRedirectPersistCleanup" type="exclusive" timeout="5" throwontimeout="false">
				<cfif (diffTimestamp - dataStorage.lastCleanup) GTE 0>
					<cfif threadingAdapter.allowThreading()>
						<cfset threadingAdapter.run(this, "reap") />
					<cfelse>
						<cfset reap() />
					</cfif>
				</cfif>
			</cflock>

		</cfif>
	</cffunction>